[Event Request] Table 5080 "To-do" - OnProcessAttendeeAppointmentOnAfterFindAttendeeTask

[KlaasKleermaker]

Why do you need this change?

In 4PS Construct we also create appointments for attendees with "Attendee Type" = Contact.

Describe the request

Dear ALAppExtensions team,

On behalf of 4PS I would like to request integration event 'OnProcessAttendeeAppointmentOnAfterFindAttendeeTask' to be added to procedure ProcessAttendeeAppointment in table 5080 "To-do".

    local procedure ProcessAttendeeAppointment(Task: Record "To-do"; var Attendee: Record Attendee)
    var
        Task2: Record "To-do";
        Salesperson: Record "Salesperson/Purchaser";
        Salesperson2: Record "Salesperson/Purchaser";
        ExchangeWebServicesServer: Codeunit "Exchange Web Services Server";
        Mail: Codeunit Mail;
        Appointment: DotNet IAppointment;
        SalesPersonList: Text;
        Body: Text;
    begin
        if CreateExchangeAppointment then
            InitializeExchangeAppointment(Appointment, ExchangeWebServicesServer);
        repeat
            //if FindAttendeeTask(Task2, Attendee) then //old
            if FindAttendeeTask(Task2, Attendee) then begin //new
                OnProcessAttendeeAppointmentOnAfterFindAttendeeTask(Attendee, Task, Task2, SalesPersonList, CreateExchangeAppointment); //new
                if Attendee."Attendee Type" = Attendee."Attendee Type"::Salesperson then
                    if Salesperson2.Get(Task2."Salesperson Code") and
                       Salesperson.Get(Task."Salesperson Code")
                    then
                        if CreateExchangeAppointment then begin
                            UpdateAppointmentSalesPersonList(SalesPersonList, Salesperson2.Name);
                            if Salesperson2."E-Mail" <> '' then
                                AddAppointmentAttendee(Appointment, Attendee, Salesperson2."E-Mail");
                        end else begin
                            Body := MakeAppointmentBody(Task, Salesperson2.Name, Salesperson.Name);
                            if Mail.NewMessage(Salesperson2."E-Mail", '', '', Task2.Description, Body, '', false) then
                                SetAttendeeInvitationSent(Attendee)
                            else
                                Message(Text023, Attendee."Attendee Name");
                        end
                    else begin
                        LogTaskInteraction(Task, Task2, true);
                        SetAttendeeInvitationSent(Attendee);
                    end;
            end; //new
        until Attendee.Next() = 0;
        if CreateExchangeAppointment and (SalesPersonList <> '') then begin
            Body := MakeAppointmentBody(Task, SalesPersonList, Salesperson.Name);
            Appointment.Body := Body;
            SaveAppointment(Appointment)
        end;
    end;

    [IntegrationEvent(false, false)]
    local procedure OnProcessAttendeeAppointmentOnAfterFindAttendeeTask(var Attendee: Record Attendee; var Task: Record "To-do"; var Task2: Record "To-do"; var SalesPersonList: Text; CreateExchangeAppointment: Boolean)
    begin
        //new
    end;

Internal work item: AB#621712

[AleksandricMarko]

Hi @KlaasKleermaker,

Thanks for submitting this extensibility request. To help us process it efficiently, please update the issue to include the required information.

📚 Extensibility Guidelines

Missing Information:

• Justification for event inside a loop: The proposed event OnProcessAttendeeAppointmentOnAfterFindAttendeeTask is located inside a repeat...until Attendee.Next() = 0 loop in the ProcessAttendeeAppointment procedure. Events inside loops may cause performance issues if subscribers perform heavy operations, as the event fires on every iteration. Please clarify:
  1. Why must the event fire on each loop iteration (per attendee)?
  2. What operations will your event subscriber perform?
  3. Have you considered an alternative location outside the loop (e.g., an event before or after the loop) that could achieve the same goal?

Please update the issue with the missing details. We'll automatically re-analyze once updated.

[KlaasKleermaker]

Hi @AleksandricMarko, thanks for your response.
Here are the answers to your questions:
i. For each Attendee we need to do something if its Attendee Type = Contact.
ii. Our event subscriber will do something similar as is done in the standard code for every iteration in the repeat loop, but then for Attendees with Attendee Type = Contact.
iii I have considerd and alternative location outside the loop, but then I have to create the same repeat loop again, which is not good for the performance.

Here is our existing code in the embedded app:

    local procedure ProcessAttendeeAppointment(Task: Record "To-do"; var Attendee: Record Attendee)
    var
        Task2: Record "To-do";
        Salesperson: Record "Salesperson/Purchaser";
        Salesperson2: Record "Salesperson/Purchaser";
        ExchangeWebServicesServer: Codeunit "Exchange Web Services Server";
        Mail: Codeunit Mail;
        Appointment: DotNet IAppointment;
        SalesPersonList: Text;
        Body: Text;
        Contact: Record Contact;
    begin
        if CreateExchangeAppointment then
            InitializeExchangeAppointment(Appointment, ExchangeWebServicesServer);
        repeat
            if FindAttendeeTask(Task2, Attendee) then
                if Attendee."Attendee Type" = Attendee."Attendee Type"::Salesperson then
                    if Salesperson2.Get(Task2."Salesperson Code") and
                       Salesperson.Get(Task."Salesperson Code")
                    then
                        if CreateExchangeAppointment then begin
                            UpdateAppointmentSalesPersonList(SalesPersonList, Salesperson2.Name);
                            if Salesperson2."E-Mail" <> '' then
                                AddAppointmentAttendee(Appointment, Attendee, Salesperson2."E-Mail");
                        end else begin
                            Body := MakeAppointmentBody(Task, Salesperson2.Name, Salesperson.Name);
                            if Mail.NewMessage(Salesperson2."E-Mail", '', '', Task2.Description, Body, '', false) then
                                SetAttendeeInvitationSent(Attendee)
                            else
                                Message(Text023, Attendee."Attendee Name");
                        end
                    else begin
                        LogTaskInteraction(Task, Task2, true);
                        SetAttendeeInvitationSent(Attendee);
                    end
                //**4PS.sn
                else
                    if Attendee."Attendee Type" = Attendee."Attendee Type"::Contact then
                        if Contact.Get(Attendee."Attendee No.") and
                           Salesperson.Get(Task."Salesperson Code")
                        then
                            if CreateExchangeAppointment then begin
                                UpdateAppointmentSalesPersonList(SalesPersonList, Contact.Name);
                                if Contact."E-Mail" <> '' then
                                    AddAppointmentAttendee(Appointment, Attendee, Contact."E-Mail");
                            end else begin
                                Body := MakeAppointmentBody(Task, Contact.Name, Salesperson.Name);
                                Clear(Mail);
                                if Mail.NewMessage(Contact."E-Mail", '', '', Task2.Description, Body, '', false) then
                                    SetAttendeeInvitationSent(Attendee)
                                else
                                    Message(Text023, Attendee."Attendee Name");
                            end
                        else begin
                            LogTaskInteraction(Task, Task2, true);
                            SetAttendeeInvitationSent(Attendee);
                        end
        //**4PS.en
        until Attendee.Next() = 0;
        if CreateExchangeAppointment and (SalesPersonList <> '') then begin
            Body := MakeAppointmentBody(Task, SalesPersonList, Salesperson.Name);
            Appointment.Body := Body;
            SaveAppointment(Appointment)
        end;
    end;

[AleksandricMarko]

✅ Analysis complete - approved for implementation

---

Implementation:

Add a new integration event in the ProcessAttendeeAppointment procedure of Table 5080 "To-do" after FindAttendeeTask succeeds, inside the loop. The existing single-statement if must be wrapped in a begin...end block.

Location in ProcessAttendeeAppointment procedure (around line 3049):

        repeat
            if FindAttendeeTask(Task2, Attendee) then begin
                if Attendee."Attendee Type" = Attendee."Attendee Type"::Salesperson then
                    if Salesperson2.Get(Task2."Salesperson Code") and
                       Salesperson.Get(Task."Salesperson Code")
                    then
                        if CreateExchangeAppointment then begin
                            UpdateAppointmentSalesPersonList(SalesPersonList, Salesperson2.Name);
                            if Salesperson2."E-Mail" <> '' then
                                AddAppointmentAttendee(Appointment, Attendee, Salesperson2."E-Mail");
                        end else begin
                            Body := MakeAppointmentBody(Task, Salesperson2.Name, Salesperson.Name);
                            if Mail.NewMessage(Salesperson2."E-Mail", '', '', Task2.Description, Body, '', false) then
                                SetAttendeeInvitationSent(Attendee)
                            else
                                Message(Text023, Attendee."Attendee Name");
                        end
                    else begin
                        LogTaskInteraction(Task, Task2, true);
                        SetAttendeeInvitationSent(Attendee);
                    end;
                OnProcessAttendeeAppointmentOnAfterFindAttendeeTask(Attendee, Task, Task2, SalesPersonList, CreateExchangeAppointment);  // <-- New event
            end;
        until Attendee.Next() = 0;

Event Publisher (add at the end of the table with other events):

    [IntegrationEvent(false, false)]
    local procedure OnProcessAttendeeAppointmentOnAfterFindAttendeeTask(var Attendee: Record Attendee; var Task: Record "To-do"; var Task2: Record "To-do"; var SalesPersonList: Text; CreateExchangeAppointment: Boolean)
    begin
    end;

---

File: Todo.Table.al

[JesperSchulz]

Thanks for reporting this. We agree, and we’ll publish a fix asap, either in an update for the current version or in the next major release. Please do not reply to this, as we do not monitor closed issues. If you have follow-up questions or requests, please create a new issue where you reference this one.

Build ID: 46795.